Syntax of MacScheme machine assembly language.  [Revision 0]

<segment>  ::=  ( <instructions> )

<instructions>  ::=  
                  |  <instruction> <instructions>

<instruction>  ::=  <pseudo>
                 |  ( <op1> <prim1> )
                 |  ( <op2> <prim2> <register> )
                 |  ( <op3> <prim3> <register> <register> )
                 |  ( <op2imm> <prim_imm> <value> )
                 |  ( <const> <value> )
                 |  ( <global> <id> )
                 |  ( <setglbl> <id> )
                 |  ( <lexical> <rib> <offset> )
                 |  ( <setlex> <rib> <offset> )
                 |  ( <stack> <int> )
                 |  ( <setstk> <int> )
                 |  ( <load> <register> <int> )
                 |  ( <store> <register> <int> )
                 |  ( <reg> <register> )
                 |  ( <setreg> <register> )
                 |  ( <movereg> <register> <register> )
                 |  ( <lambda> <segment> <int> <doc> )
                 |  ( <lexes> <int> <doc> )
                 |  ( <invoke> <int> )
                 |  ( <save> <int> )
                 |  ( <setrtn> <L> )
                 |  ( <pop> <int> )
                 |  ( <return> )
                 |  ( <nop> )
                 |  ( <jump> <rib> <int> <live> )
                 |  ( <skip> <L> <live> )
                 |  ( <branch> <L> <live> )
                 |  ( <branchf> <L> <live> )

<pseudo>  ::=  ( <label> <L> )
            |  ( <proc> )
            |  ( <cont> )
            |  ( <align> <int> )

<register>  ::=  <int>
<rib>       ::=  <int>
<offset>    ::=  <int>
<live>      ::=  <int>
<L>         ::=  <int>
<doc>       ::=  #( <id> #f <int> #f #f #f )

<prim1>     ::=  unspecified  |  not  |  fx--
              |  fxzero?  |  fxpositive?  |  fxnegative?  |  ...

<prim2>     ::=  <prim_imm>  |  fx*  |  ...

<prim_imm>  ::=  fx+  |  fx-
              |  fx=  |  fx<  |  fx<=  |  fx>  |  fx>=
              |  eq?  |  make-vector  |  vector-ref  |  ...

<prim3>     ::=  vector-set!  |  ...